NeoPixel Ring Bangle Bracelet with GEMMA

Wear a bangle of light! Build a charming bracelet from four NeoPixel rings and GEMMA, Adafruit’s tiny wearable electronics platform. You will need:

To keep up with what I’m working on, follow me on YouTube, Instagram, Twitter, Pinterest, and subscribe to my newsletter. As an Amazon Associate I earn from qualifying purchases you make using my affiliate links.

Circuit Diagram

Click to enlarge. GEMMA’s D1 pin is wired to the first pixel ring’s input pin. Signal output of first ring chains to subsequent ring’s input pin, and so on.

GEMMA’s Vout pin is wired to all four pixel ring’s VCC pins. Likewise GEMMA’s ground pin is wired to all the rings’ GND pins.

Build It!

Lay out four NeoPixel rings on a gridded surface like a cutting mat. Glue on your metal jewelry findings as shown with E6000 craft adhesive and let dry overnight.

The orientation of the rings in the photo above matches up with our coding diagram on the next page. This orientation affects how any multi-ring animations will look!

Open your jump rings by twisting the wire ends away from each other with two pairs of pliers. Torque the wire ends, don’t splay them.

Use your jump rings to attach the jewelry findings to one another, and also to attach a magnetic clasp.

Close jump rings the same way you opened them: twist the wire ends towards each other with two pairs of pliers until they match up.

Follow the circuit diagram to connect GEMMA and the four NeoPixel Rings. Use small-gauge stranded wire, and route the wires through the jump rings so they are hidden from the front side of the pixel rings.

Make sure that the wires are not under strain– they should be long enough to allow the segments of the bracelet to move semi-freely without tugging. The metal findings/jump ring should be responsible for strain relief.

When soldering power and ground connections, where more than one wire will affix to each joint, put both wires in at once before soldering. It’s easier to solder two wires at once than it is to solder one wire in, then have to reheat the solder to add another.

You are making a piece of delicate jewelry, but you’ll wear it out on your wrist, so there’s a chance your wires could get snagged! To provide extra strain relief, add a dot of E6000 over each solder connection on the NeoPixel rings.

To add a power switch, cut and strip one of the wires leading to your battery.

Add two small pieces of heat shrink tubing to the stripped wires and solder to two legs of the small switch (center leg and one outer leg). Slide the heat shrink to cover the exposed metal and shrink with a heat gun.

Use a piece of foam tape to stick the battery behind the GEMMA, with the switch sticking out the side. Plug in the battery and glue the switch in place.

Arduino Code

To program GEMMA, make sure you have set up the Arduino IDE as explained in the “Introducing GEMMA” guide. Also, you’ll need the NeoPixel library installed as explained in the NeoPixel Überguide.

bove is a diagram numbering the NeoPixels in their programatic order. It’s handy for writing animations that seem to flow between rings, like the basic sine wave animation here:

Download all the sample codes in this zip file or copy and paste from the blocks below.

NeoPixel_Ring_Bangle_Bracelet.zipDownload
//Basic sine wave animation for NeoPixel Ring Bangle Bracelet
//by Dano Wall and Becky Stern for Adafruit Industries
#include <Adafruit_NeoPixel.h>

#define PIN       1 // Marked D1 on GEMMA
#define NUM_LEDS 64

// Parameter 1 = number of pixels in strip
// Parameter 2 = pin number (most are valid)
// Parameter 3 = pixel type:
//   NEO_GRB  Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB  Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, PIN, NEO_GRB);

uint32_t color = strip.Color(75, 250, 100); // Change RGB color value here

// These are the pixels in order of animation-- 36 pixels in total:
int sine[] = {
   4,  3,  2,  1,  0, 15, 14, 13, 12, 20, 21, 22, 23, 24, 25, 26, 27, 28,
  36, 35, 34, 33, 32, 47, 46, 45, 44, 52, 53, 54, 55, 56, 57, 58, 59, 60 };

void setup() {
  strip.begin();
  strip.show();            // Initialize all pixels to 'off'
  strip.setBrightness(40); // 40/255 brightness (about 15%)
}

void loop() {
  for(int i=0; i<36; i++) {
    strip.setPixelColor(sine[i], color);             // Draw 'head' pixel
    strip.setPixelColor(sine[(i + 36 - 8) % 36], 0); // Erase 'tail'
    strip.show();
    delay(40);
  }
}

Here’s another fun animation, it’s similar to the sine wave but loops back around on itself when it gets to the fourth ring in a “figure eight.”

//Figure-Eight animation for Neopixel Ring Bangle Bracelet
//By Dano Wall and Becky Stern for Adafruit Industries
#include <Adafruit_NeoPixel.h>

#define PIN       1 // Marked D1 on GEMMA
#define NUM_LEDS 64

// Parameter 1 = number of pixels in strip
// Parameter 2 = pin number (most are valid)
// Parameter 3 = pixel type:
//   NEO_GRB  Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB  Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, PIN, NEO_GRB);

uint32_t color = strip.Color(5, 250, 200); // Change RGB color value here

// Array of pixels in order of animation - 70 in total:
int sine[] = {
   4,  3,  2,  1,  0, 15, 14, 13, 12, 20, 21, 22, 23, 24, 25, 26, 27, 28,
  36, 35, 34, 33, 32, 47, 46, 45, 44, 52, 53, 54, 55, 56, 57, 58, 59, 60,
  61, 62, 63, 48, 49, 50, 51, 52, 44, 43, 42, 41, 40, 39, 38, 37, 36, 28,
  29, 30, 31, 16, 17, 18, 19, 20, 12, 11, 10,  9,  8,  7,  6,  5 };

void setup() {
  strip.begin();
  strip.show();            // Initialize all pixels to 'off'
  strip.setBrightness(40); // 40/255 brightness (about 15%)
}

void loop() {
  for(int i=0; i<70; i++) {
    strip.setPixelColor(sine[i], 0);                 // Erase 'tail'
    strip.setPixelColor(sine[(i + 10) % 70], color); // Draw 'head' pixel
    strip.show();
    delay(60);
  }
}

This code randomly flashes pixels in three colors of your choice.

//Random Flash animation for Neopixel Ring Bangle Bracelet
//by Dano Wall and Becky Stern for Adafruit Industries
//based on the Sparkle Skirt, minus the accelerometer
#include <Adafruit_NeoPixel.h>

#define PIN       1 // Marked D1 on GEMMA
#define NUM_LEDS 64

// Parameter 1 = number of pixels in strip
// Parameter 2 = pin number (most are valid)
// Parameter 3 = pixel type:
//   NEO_GRB  Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB  Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, PIN, NEO_GRB);

// Here is where you can put in your favorite colors that will appear!
// just add new {nnn, nnn, nnn}, lines. They will be picked out randomly
uint8_t myColors[][3] = {
  {232, 100, 255}, // purple
  {200, 200,  20}, // yellow
  { 30, 200, 200}, // blue
};

// don't edit the line below
#define FAVCOLORS sizeof(myColors) / 3

void setup() {
  strip.begin();
  strip.show();            // Initialize all pixels to 'off'
  strip.setBrightness(40); // 40/255 brightness (about 15%)
}

void loop() {
  flashRandom(5); // Number is 'wait' delay, smaller num = faster twinkle
}

void flashRandom(int wait) {

  // pick a random favorite color!
  int c     = random(FAVCOLORS);
  int red   = myColors[c][0];
  int green = myColors[c][1];
  int blue  = myColors[c][2];

  // get a random pixel from the list
  int j = random(strip.numPixels());

  // now we will fade in over 5 steps
  for (int x=1; x <= 5; x++) {
    int r = red   * x / 5;
    int g = green * x / 5;
    int b = blue  * x / 5;

    strip.setPixelColor(j, strip.Color(r, g, b));
    strip.show();
    delay(wait);
  }
  // & fade out in 5 steps
  for (int x=5; x >= 0; x--) {
    int r = red   * x / 5;
    int g = green * x / 5;
    int b = blue  * x / 5;

    strip.setPixelColor(j, strip.Color(r, g, b));
    strip.show();
    delay(wait);
  }
  // LED will be off when done (they are faded to 0)
}

Wear it!

Enjoy your new bangle bracelet! Perfect a New Year’s party, sporting event (with team colors, of course), wedding, bat mitzvah, quinceañera, and more.

Originally posted on Adafruit

Thanks for following along! If you enjoyed your experience, please share this guide with a friend.

If you like this project, you may be interested in some of my others:

To keep up with what I’m working on, follow me on YouTube, Instagram, Twitter, and Pinterest.

Related Posts

%d bloggers like this: